home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Night Owl 6
/
Night Owl's Shareware - PDSI-006 - Night Owl Corp (1990).iso
/
008a
/
tbscan30.zip
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1991-11-17
|
4KB
|
96 lines
@echo off
echo off
if '%1'=='' goto help
if not exist TbScan.Pgm goto err1
echo INSTALLATION TBSCAN
echo ───────────────────────────────────────────────────────────────────────
echo TbScan is no longer a COM file but an EXE file!
echo If there is a COM and a EXE file with the same name,
echo DOS executes the COM file.
echo To make sure that TbScan.EXE file will be executed,
echo all TbScan.COM files have to be deleted!
echo This installation batch file deletes the TbScan.COM
echo file in the target directory automatically.
echo However, if there are other TbScan.COM files on your system,
echo you should delete them manually.
rem If a file with urgent information exists print it now
if exist Readme.Now type Readme.Now
echo ───────────────────────────────────────────────────────────────────────
rem TbScan.Exe should not exist in current directory
if exist TbScan.Exe del TbScan.Exe >nul
rem Make directory if it does not exist
if not exist %1\nul md %1
rem Directory should now exist
if not exist %1\nul goto err2
rem Delete TbScan.COM if it is there
if exist %1\TbScan.Com del %1\TbScan.Com >nul
rem Install the new TbScan.Exe file
copy TbScan.Pgm %1\TbScan.Exe >nul
rem The file should have been copied
if not exist %1\TbScan.Exe goto err3
rem If the directory specified is the current directory we are ready
if exist TbScan.Exe goto ready
rem Copy the remaining files to the target directory
if exist *.avr copy *.avr %1\*.avr >nul
if exist *.dat copy *.dat %1\*.dat >nul
if exist TbScan.Hlp copy TbScan.Hlp %1\TbScan.Hlp >nul
if exist TbScan.Msg copy TbScan.Msg %1\TbScan.Msg >nul
if exist TbScan.Doc copy TbScan.Doc %1\TbScan.Doc >nul
if exist TbScan.Key copy TbScan.Key %1\TbScan.Key >nul
if exist Report.Doc copy Report.Doc %1\Report.Doc >nul
if not exist Tbs.Bat goto label1
rem If there is already a Tbs.Bat in the target directory do not destroy it
if not exist %1\Tbs.Bat copy Tbs.Bat %1\Tbs.Bat >nul
:label1
rem If we are installing the evaluation version copy the Register.Doc file too
if not exist TbScan.Key copy Register.Doc %1\Register.Doc >nul
if not exist TbScan.New goto ready
rem If the target directory contains an old TbScan.NEW file update it
if exist %1\TbScan.New copy TbScan.New %1\TbScan.New >nul
:ready
echo ───────────────────────────────────────────────────────────────────────
echo TbScan is now installed. It is recommended to print or read the file
echo TbScan.Doc. To run TbScan type "%1\TbScan C:\".
echo Type "%1\TbScan -help" to get a help screen.
if not exist InstallX.Bat goto end
echo ───────────────────────────────────────────────────────────────────────
echo ───────────────────────────────────────────────────────────────────────
echo To install TbScanX too, you should run the batch file "InstallX".
goto end
:err1
echo ───────────────────────────────────────────────────────────────────────
echo Error: TbScan.Pgm not found in current directory.
echo Change to the drive and directory containing this file.
goto end
:err2
echo ───────────────────────────────────────────────────────────────────────
echo Error: Can not create directory %1\
echo Invalid path or write protected disk.
echo You should NOT specify a trailing backslash (\).
goto end
:err3
echo ───────────────────────────────────────────────────────────────────────
echo Error: Can not copy TbScan.Pgm to %1\TbScan.Exe
echo Disk probably full or write protected.
goto end
:help
echo ───────────────────────────────────────────────────────────────────────
echo This installation batch file installs the TbScan virus detector.
echo You have to specify the directory where TbScan has to be installed.
echo If the directory does not exist it will be created.
echo Do NOT specify a trailing backslash (\).
echo Examples:
echo install c:
echo install d:\tb
:end
echo ───────────────────────────────────────────────────────────────────────